@echo off
setlocal

set "REPO_URL=https://git.gurusushi.dyndns.org/guru/Video-Processing-Scripts.git"
set "BRANCH=master"
set "SCRIPT_DIR=%~dp0"

cd /d "%SCRIPT_DIR%"
if errorlevel 1 (
    echo Failed to change directory to %SCRIPT_DIR%
    exit /b 1
)

where git >nul 2>&1
if errorlevel 1 (
    echo Error: git is not installed or not in PATH.
    exit /b 1
)

if exist ".git" (
    echo Updating existing repository in %SCRIPT_DIR%
    git remote set-url origin "%REPO_URL%"
    if errorlevel 1 (
        echo git remote set-url failed.
        exit /b 1
    )
    git fetch origin %BRANCH%
    if errorlevel 1 (
        echo git fetch failed.
        exit /b 1
    )
    git checkout %BRANCH%
    if errorlevel 1 (
        echo git checkout failed.
        exit /b 1
    )
    git pull --ff-only origin %BRANCH%
    if errorlevel 1 (
        echo git pull failed.
        exit /b 1
    )
) else (
    echo Cloning repository into %SCRIPT_DIR%
    git clone --branch %BRANCH% "%REPO_URL%" .
    if errorlevel 1 (
        echo git clone failed.
        exit /b 1
    )
)

echo Done.
endlocal
pause